SetCompressor LZMA
 
; Variables
 
var RESOLUME_PATH
var FLOWMOTION_PATH
var VJO_PATH
var ELEKTRONIKA_PATH
 
; Defines
 
!define NAME_RESOLUME "veejayPack for Resolume 2.3"
!define NAME_FLOWMOTION "veejayPack for Flowmotion 2.x"
!define NAME_VJO "veejayPack for VJo R3.5"
!define NAME_ELEKTRONIKA "veejayPack for Elektronika 2.x"
!define NAME_MAIN "veejayPack dll's"
!define NAME_BASE "Required libraries"
 
!define DESC_RESOLUME "Install veejayPack direct into Resolume 2.3 plugins dir"
!define DESC_FLOWMOTION "Install veejayPack direct into Flowmotion 2.x plugins dir"
!define DESC_VJO "Install veejayPack direct into VisualJockey's FreeFrameHost plugins dir"
!define DESC_ELEKTRONIKA "Install veejayPack direct into Elektronika 2.x plugins dir"
!define DESC_MAIN "Install veejayPack effects into selected directory"
!define DESC_BASE "Installs libraries required for veejayPack effects"
 
!define PRODUCT_NAME "veejayPack"
!define PRODUCT_VERSION "1.1"
!define PRODUCT_PUBLISHER "visualvinyl.net"
!define PRODUCT_WEB_SITE "http://freeframe.visualvinyl.net"
 
!define LOGICLIB_STRCMP
!define LOGICLIB_SECTIONCMP
 
; Includes
 
!include "LogicLib.nsh"
!include "MUI.nsh"
 
; MUI
 
!define MUI_HEADERIMAGE
!define MUI_HEADERIMAGE_BITMAP "veejay-top-l-v11.bmp"
!define MUI_WELCOMEFINISHPAGE_BITMAP "veejay-wizard-v11.bmp"
!define MUI_COMPONENTSPAGE_CHECKBITMAP "veejay-checks.bmp"
!define MUI_INSTFILESPAGE_COLORS "DEE7EC 324163"
!define MUI_INSTFILESPAGE_PROGRESSBAR colored
 
!define MUI_ABORTWARNING
!define MUI_ICON "vv.ico"
!define MUI_COMPONENTSPAGE_SMALLDESC
!define MUI_FINISHPAGE_NOAUTOCLOSE
 
!define MUI_LICENSEPAGE_TEXT_TOP "Latest changes and license agreement:"
!define MUI_LICENSEPAGE_TEXT_BOTTOM "For more informations/updates/etc about this plugin package go to http://freeframe.visualvinyl.net"
!define MUI_LICENSEPAGE_BUTTON "I agree"
 
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_LICENSE "veejay-license.rtf"
 
PageEx license
  LicenseData "veejay-changelog.rtf"
  LicenseText " " "Next >"
PageExEnd
 
!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
 
!insertmacro MUI_LANGUAGE "English"
 
; Begin
 
Name "${PRODUCT_NAME} ${PRODUCT_VERSION}"
OutFile "veejayPack-v${PRODUCT_VERSION}-setup.exe"
InstallDir "$PROGRAMFILES\vvFFPP"
ShowInstDetails show
 
; Sections
 
Section "${NAME_BASE}" BASE
  SetOutPath "$SYSDIR"
  SetOverwrite ifnewer
  File "msvcr80.dll"
  SetOutPath "$INSTDIR"
  SetOverwrite ifnewer
  File "F:\dev\_local_\freeframe\testing\FreeframeLister.exe"
  CreateDirectory "$SMPROGRAMS\vvFFPP"
  CreateShortCut "$SMPROGRAMS\vvFFPP\FreeFrame Lister.lnk" "$INSTDIR\FreeframeLister.exe"
SectionEnd
 
Section "${NAME_MAIN}" MAIN
  SetOutPath "$INSTDIR\plugins"
  SetOverwrite ifnewer
  File "F:\dev\_local_\freeframe\rel\veejay*.dll"
SectionEnd
 
  Section /o "-$NAME_RESOLUME" RESOLUME
    SetOutPath $RESOLUME_PATH
    SetOverwrite ifnewer
    File "F:\dev\_local_\freeframe\rel\veejay*.dll"
  SectionEnd
 
  Section /o "-$NAME_FLOWMOTION" FLOWMOTION
    SetOutPath $FLOWMOTION_PATH
    SetOverwrite ifnewer
    File "F:\dev\_local_\freeframe\rel\veejay*.dll"
  SectionEnd
 
  Section /o "-$NAME_VJO" VJO
    SetOutPath $VJO_PATH
    SetOverwrite ifnewer
    File "F:\dev\_local_\freeframe\rel\veejay*.dll"
  SectionEnd
 
  Section /o "-$NAME_ELEKTRONIKA" ELEKTRONIKA
    SetOutPath $ELEKTRONIKA_PATH
    SetOverwrite ifnewer
    File "F:\dev\_local_\freeframe\rel\veejay*.dll"
  SectionEnd
 
Section -AdditionalIcons
  WriteIniStr "$INSTDIR\${PRODUCT_NAME}.url" "InternetShortcut" "URL" "${PRODUCT_WEB_SITE}"
  CreateShortCut "$SMPROGRAMS\vvFFPP\vvFFPP Website.lnk" "$INSTDIR\${PRODUCT_NAME}.url"
SectionEnd
 
; Functions
 
Function .onInit
  Call GetPaths
FunctionEnd
 
Function GetPaths
  ReadRegStr $RESOLUME_PATH HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Resolume 2.3_is1" "InstallLocation"
  ${If} $RESOLUME_PATH != ""
    StrCpy $RESOLUME_PATH "$RESOLUME_PATHplugins"
    SectionSetText ${RESOLUME} "${NAME_RESOLUME}"
    SectionSetFlags ${RESOLUME} 9
  ${EndIf}
 
  ReadRegStr $FLOWMOTION_PATH HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Robotfunk Flowmotion_is1" "InstallLocation"
  ${If} $FLOWMOTION_PATH != ""
    StrCpy $FLOWMOTION_PATH "$FLOWMOTION_PATHFreeframe"
    SectionSetText ${FLOWMOTION} "${NAME_FLOWMOTION}"
    SectionSetFlags ${FLOWMOTION} 9
  ${EndIf}
 
  ReadRegStr $VJO_PATH HKCU "Software\Visualight\DFX\FreeFramehost" "PluginPath"
  ${If} $VJO_PATH != ""
    SectionSetText ${VJO} "${NAME_VJO}"
    SectionSetFlags ${VJO} 9
  ${EndIf}
 
  ReadRegStr $ELEKTRONIKA_PATH HKLM "SOFTWARE\sisetsea\elektro20" ""
  ${If} $ELEKTRONIKA_PATH != ""
    StrCpy $ELEKTRONIKA_PATH "$ELEKTRONIKA_PATH\Freeframe"
    SectionSetText ${ELEKTRONIKA} "${NAME_ELEKTRONIKA}"
    SectionSetFlags ${ELEKTRONIKA} 9
  ${EndIf}
 
FunctionEnd
 
; Descriptions
 
!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
!insertmacro MUI_DESCRIPTION_TEXT ${ELEKTRONIKA} "${DESC_ELEKTRONIKA}"
!insertmacro MUI_DESCRIPTION_TEXT ${RESOLUME} "${DESC_RESOLUME}"
!insertmacro MUI_DESCRIPTION_TEXT ${FLOWMOTION} "${DESC_FLOWMOTION}"
!insertmacro MUI_DESCRIPTION_TEXT ${VJO} "${DESC_VJO}"
!insertmacro MUI_DESCRIPTION_TEXT ${MAIN} "${DESC_MAIN}"
!insertmacro MUI_DESCRIPTION_TEXT ${BASE} "${DESC_BASE}"
!insertmacro MUI_FUNCTION_DESCRIPTION_END